HomeHome  FAQFAQ  SearchSearch  RegisterRegister  MemberlistMemberlist  UsergroupsUsergroups  Log inLog in  


 Macro help

Go down 


Posts : 26
Join date : 2007-07-31

Macro help Empty
PostSubject: Macro help   Macro help Icon_minitimeThu Aug 02, 2007 10:03 pm

Here is a list modifining it Still oncomplete
/cast Spellname
/cast Spellname(Rank X)
/petfollow [option]
/petattack [option] <optinal target>
/equip Itemname <-- Equips an item
/equipslot X itemname <-- Equips an item in slot X (usefull for equipping a weapon in offhand etc.). See a list of slots here: http://tinyurl.com/vnm39
/swapactionbar 1 2 <--- Swaps between action bar 1 and 2
/cancelaura [option] name <--- Will cancel a buff on you, example: /cancelaura Swift White Mechanostrider
/castrandom spell1, spell2, spell3 <--- Randomly casts one of the follow spells. Ranks are useable eg. spell(Rank x)
/userandom <--- Same as above, but with consumeable items
/cleartarget <-- Clears current target
/stopmacro [option] <--- Stops the macro from completing running if a special requirement is met. See below for an explenation of [option]
/castsequence spell1, spell2, spell3 <--- Casts spell in a sequense aka. first it casts spell1, then spell2 etc.
/petautoattackon <spell> or /petautoattackoff <spell>
/targetenemy -- only called once per macro
/targetfriend -- only called once per macro

If /targetenemy, /targetfriend, /targetparty or /targetraid comes without anything else they will use the closest person (aka. the TargetNearest function). You can also use /targetraid 1 to target next raid member or /target 0 to target the previous raid member (works with all of the above). Works with [options], aka. /targetenemy [modifier:shift] 1; 0

Now, only being able to use /cast, /petattack etc. is very limited, to Slouken has in Cooperation with the WoW US players Cogwheel and Tem created an option system for the macro system. To absically explain, you specify some options that depending on conditions return true or flase. If an option returns false, then that part of the macro will skip that part and go to next option set.
/cast [option1,option2] Spell

The above macro will in TBC cast Greater heal if the above options both return true. The "," between option1 and option2 signifies "AND", which means that if both conditions (option 1 and 2) return true, then the spell will fire.

/cast [harm] Smite; [help] Greater Heal

Will cast Smite if the target is hostile. If the target is not hostile it will jump to the next part of the macro and try to cast Greater Heal if the target is friendly.

Another example:
/cast [modifier:shift] Vampiric Embrace; Shadow Word: Pain

This will cast Vampiric Embrace if the shift key is held down when clicking the macro. Else it will cast Shadow Word: Pain.

You can use a Slash ("/") to specify an "OR" command, aka. if any of the options return true then the macro will fire instead of "," ("AND").

Here is the full list of option commands:
[help] - Returns True if the target is friendly
[harm] - Returns true if target is hostile
[combat] or [nocombat] - Returns true if you are in combat (or aren't in combat if you use the 'no' prefix before combat). If used with /petattack or /petfollow ir will return true if your pet is in combat or not.
[modifier:alt|shift|ctrl] or [nomodifier:alt|shift|control] - Returns true if the designated modifier key is down. Example:

[modifier:shift,modifier:alt] <-- Returns true if BOTH the shift and alt buttons are down when the macro is executed
[modifier:shift/alt] <-- Returns true if either of the two modifier buttons are pressed down when the macro is clicked
[nomodifier:shift/alt] <-- Returns true if neither shift nor alt is pressed down

[exist] or [noexist] <-- Returns true if the designated target exists or don't exist.
[dead] or [nodead] <-- Returns true if the designated target is dead or alive.
[target=x] - Sets the target of the macro. Example:

[target=name,exists] - Returns true if the designated target exists AND it will also force the spell to be cast on that player/unit. /cast [target=targettarget,exists,help] Greater Heal will cast Greater Heal on your targets target is that unit exists and is able to recieve a Greater Heal from you.
[target=none] will request manual targeting for the spell so you have to click a player or unit to cast it on him/her
[target=party2] will make the spell hit party member 2
[target=targettarget] will make the spell hit your targets target. Adding an exist option to this one is recommended.

[stance:x] or [nostance:x] - Returns true if you are or aren't in the appropriate stance. X is a numbers. Example:

/cast [stance:1,nocombat] Charge; Battle Stance will cast charge if you are out of combat and in Battle Stance, else it will shift to battle stance. Stances are numbered in the order you have them. For warriors this will (assuming they got all stances) be 1 = battle stance, 2 = defensive stance, 3 = berserker stance, for druids 1 = bear form, 2 = aquatic form, 3 = cat form etc. It is worth noting that stance:x DOES NOT APPLY TO PALADIN AURAS OR HUNTER ASPECTS as they aren't considered shapeshifts. Should work for rogues stealth (in addition to the stealth command below) and priests in Shadowform.
You also don't have to specify an x stance if you are a class that can leave their stance (aka. a druid in caster form or a priest out of shadow form can use [nostance] to return true).

[stealth] - Returns true if you are stealthed. Should work for both rogues and druids.
[equipped:itemtype] - Returns true if the currenct item subtype is equipped or not. Example: [item:daggers] would both return true if you have a dagger equipped. Also works for Shields and all other items. http://www.wowwiki.com/ItemType for a full list of itemtypes.
[swimming][flying][mounted] [indoors] [outdoors] - Should be given
[pet] or [nopet] - Returns true if your pet is active
[pet:name/type] - Returns true if your pet name or type matches, like [pet:snowfrenzy] or [pet:wolf/bear/succubus]
[button:x] - Returns true if a specified button was used to execute the macro:
[button:1] or [button:LeftButton] = You used the assigned keybinding or a left mouse click to activate the macro
2 or RightButton
3 or MiddleButton
4 or Button4
5 or Button5
/cast [button:1] Flash Heal; [button:2] Greater Heal will cast Flash heal if you used the assigned keyboard button or left mouse button to click the macro, and will cast Greater Heal if you rightclicked the macro.

[channeling] or [channeling:spell] - Returns true if you are channeling a random spell or a specific spell. [nochanneling] or [nochanneling:spell] also works. Usefull when you don't want a macro to break something when you are channeling, say Mind Flay or so.
[party] or [raid] - Target is a member of your party/raid ([raid] ALSO applies if you are in a standard party)
[group] or [group:party] or [group:raid] - You are a member of a group or a specific type of group.

Focus is a new feature allowing you to save a target. Example:
/focus target
...will save your currect target as your focus. This means that you at any time can use /target focus to target the unit you designated with /focus target.

Focus supports option parameters. Example macro:
/cast [target=focus,exists] Polymorph (/castrandom [target=focus,exists] Polymorph, Polymorph: Pig, Polymorph: Turtle <--- If you want a random Polymorph)

This works like your "personal" raid icon which makes it easy to keep track of sheeps etc.

Hover Targeting:
A feature that i posted my concerns about on the US forums has been saved (but only because Slouken is so freaking awesome). We are talking Hover Targeting, or the ability to dynamically cast spells on different players without having to target them, but by just hovering your mouse cursor over a protected unit frame (in this case a party/raid/target/targettarget unitframe). Example:
/cast [target=mouseover,exist] Healing Touch; Healing Touch
...will cast Healing Touch on the person which unitframe is being hovered over by your mouse, regardsless of your current target. This works with modifier keys and can do different stuff if you are not hovering over a unitframe. Ill give a more advanced macro:
/cast [target=mouseover,exist,nomodifier:shift/ctrl/alt] Swiftmend; [target=mouseover,exist,modifier:shift] Healing Touch; [target=mouseover,exist,modifier:ctrl] Rejuvenation; [target=mouseover,exist,modifier:alt] Regrowth; [modifier:ctrl] Cat Form; [modifier:shift] Dire Bear Form; [noswimming] Travel Form; [swimming] Aquatic Form
...would cast Swiftmend/Rejuvenation/Regrowth/Healing Touch if your mouse is hovering over a UnitFrame depending on which modifier keys you have pressed down. If your mouse, however, is NOT over a Unit Frame (but some other random place on the screen) it will shapeshift depending on the options you specified. In other words, you will technically have put all your standard healing spells
Back to top Go down
View user profile


Posts : 26
Join date : 2007-07-31

Macro help Empty
PostSubject: Re: Macro help   Macro help Icon_minitimeThu Aug 02, 2007 10:04 pm

/cast Greater Heal
Very simple macro which casts Greater Heal on your target.

/cast [help] Greater Heal
One option added. Will cast Greater Heal IF the target is friendly.

/cast [help] Greater Heal; Smite
Second spell added. Since it has no option added to it, it will be cast any time the first option fails.

/cast [help, combat] Flash Heal; [help, nocombat] Greater Heal; Smite
This macro will cast Flash Heal on a friendly target if you (not the target) are in combat. If you are not in combat and the target is friendly, it will cast Greater Heal. If neither of these is true (i.e. the target is not friendly) it will cast Smite.

/cast [help] Greater Heal; [harm, combat] Smite; [harm, nocombat] Mind Flay
This will cast Greater Heal on a friendly target, or Smite if the player is in combat, or Mind Flay if the player is not in combat.

/cast [stealth] Ambush; Backstab
This will cast Ambush if the player is stealthed, Backstab if not.

/cast [nostealth] Backstab; Ambush
Does the exact same thing as above, just in a different way.

/cast [actionbar:1] Greater Heal; [actionbar:2] Smite
Will cast Greater Heal if the current actionbar is #1, Smite if it is #2, nothing if actionbars 3+ are selected

/cast [harm] Polymorph
/stopmacro [noharm]
/p Sheeping %t! DO NOT TOUCH!
This macro will cast Polymorph if the target is hostile, then stop the macro if the target is NOT hostile (i.e. if the polymorph didn't go off). Then it tells the party that it's target has been Sheeped. Note that because of the '/stopmacro' command, if the target was not sheeped, the party would not be sent a tell (thus cutting down on unneccessary spam).

/cast [pet] Call Pet; Revive Pet
This macro will call your pet if you do not have one, otherwise it attempts to cast Revive Pet.

/cast [pet:owl] Dive; [pet:cat] Dash; [pet] Growl
This macro will cast Dive if you have an owl, Dash if you have a cat, or Growl if you have anything else.

/cast [pet:Voidwalker] Sacrifice; [pet:succubus] Seduction
Will cast Sacrifice if you have a Voidwalker out, Seduction if you have a Succubus.

/use [nomounted,outdoors] Black War Steed Bridle
This will attempt to mount if you are outside and not mounted.

/cast [target=pet,dead] Revive Pet; [nopet] Call Pet; Mend Pet
This will revive your pet if it's dead, call your pet if you don't have him out, or mend your pet.


Stances work the same way. If no stance number is given, then it evaluates to 'true' if the player is in any stance. (Note that for Warriors, you are ALWAYS in some stance). If a number is given, it checks to see if that form is currently active.

Each class has different numbers for it's stances. Here is a list of stances and their numbers:

Class: Warrior Priest Druid Rogue


Stance:1 Battle Shadowform Bear Stealth


Stance:2 Defensive Aquatic


Stance:3 Berserker Cat


Stance:4 Travel


Stance:5 Moonkin/Tree


Paladin Auras are no longer treated as Stances by the Macro Option system.

Keep in mind that if you skip a stance (like a Warrior who never does the Defensive Stance quest) then your stance numbers will drop down, i.e. Berserker Stance would be stance 2.

Some stance examples.
/cast [nostance] Bear Form
If you are not in a form, this will shift you into bear form.

/cast [stance:1] Overpower; [stance:2] Sunder Armor; [stance:3] Whirlwind
Will cast Overpower in Battle stance, Sunder Armor in Defensive, and Whirlwind in Berserker stance

/cast [stance:1] Growl; [stance:3] Claw
Will cast Growl in Bear form, or Claw in Cat form.

/cast [nostance:3] Cat Form
Will put you into cat form if you are not. If you are currently in Cat form, this will NOT shift you out.
Back to top Go down
View user profile


Posts : 26
Join date : 2007-07-31

Macro help Empty
PostSubject: Re: Macro help   Macro help Icon_minitimeThu Aug 02, 2007 10:04 pm

The [equipped] option also works the same way, but it's a bit trickier. The argument can be either an Inventory Slot (see below), an item type, or an item subtype. For a list of item types and subtypes, check here: http://www.wowwiki.com/ItemType

A List of Inventory Slots:
Held In Off-hand
Off Hand
Thrown (ranged slot items like thrown daggers)
Main Hand
Off Hand

Some equipped examples:

/cast [equipped:Two-Handed Swords] Mortal Strike; Heroic Strike
This will cast Mortal Strike if you are using a 2hand sword.

/cast [equipped:Two-Handed Swords/Two-Handed Maces/Two-Handed Axes/Polearms] Mortal Strike
This uses the '/' modifier to set up an 'or' condition. This macro will cast Mortal Strike if ANY of those types are equipped.

/cast [equipped:Shields] Shield Bash
This will cast Shield Bash if you have a shield equipped.

/cast [equipped:Shields, equipped:Daggers] Shield Slam
This will cast Shield slam only if you have a dagger AND a shield equipped.

/cast [noequipped:Shields, equipped:Off Hand] Rampage
This will cast Rampage if you do NOT have a shield equipped, AND you have something in the Off Hand slot. In theory, this macro will only activate if you are dual-wielding.
Back to top Go down
View user profile


Posts : 26
Join date : 2007-07-31

Macro help Empty
PostSubject: Re: Macro help   Macro help Icon_minitimeThu Aug 02, 2007 10:04 pm

New Command: /castsequence

There's a new command in WoW 2.0, called /castsequence. It allows you to set up a series of spells to cast one after another, on each subsequent click of the macro. The format is:

/castsequence [<options>] reset=<#>/target/combat <spell1>, <spell2>, <spell3>

"Huh? Say what?"

It sets up a list of spells, and the first time you click the macro, it casts the first spell on the list. The next time you click it, it will cast the second spell, and so on. When it gets to the end, it goes back to the beginning.

"I'm still not following you."

Ok, lets say you are a mage. Sometimes you need to Frost Nova and Blink away quickly. You can't do them both at the same time, so you set up a sequence to do it!

/castsequence Frost Nova, Blink

And there you have it. The first time you click it, you Frost Nova, then you click again and Blink away.

"And what happens if Frost Nova is on cooldown? Does it Blink instead? Or does it just skip over Frost Nova and do Blink on the next click?"

Neither one. If the spell fails to cast (due to cooldown, out of range, not enough mana, whatever) then the sequence does NOT go to the next spell. The next time you click the macro, it'll try to Frost Nova again. (NOTE: A resist, dodge, parry, etc does NOT count as a failed cast. The spell/ability successfully went off, it just missed.)

"What if I'm not in combat? I don't want to waste a Frost Nova if I'm not actually fighting."

You can still use all the same macro options (however, you cannot set options for each individual spell, only for the whole sequence. Sorry.)

/castsequence [combat] Frost Nova, Blink

"Eh, I was just kidding about that combat stuff. Ok, so what happens if I Frost Nova, and decide not to Blink away? The next time I want to Frost Nova, it'll be stuck on the 'Blink' setting?"

Not a problem. We'll use the new "reset" setting. Since Frost Nova has a cooldown of 24 seconds normally, we'll set the sequence to reset after 24 seconds of non-use.

/castsequence reset=24 Frost Nova, Blink

The first time you click your macro, it will Frost Nova. If you decide not to Blink, after 24 seconds it will reset back to Frost Nova. Since Frost Nova's cooldown also happens to be 24 seconds, it'll be ready to use again. Brilliant!

"Ok, that's great and all, but I'm actually a warlock, dude."

Of course you are. Well, as a warlock, I'm sure you cast the same 3 DoTs over and over again. Now you can set a sequence for those and save button space.

/castsequence Corruption, Immolate, Curse of Agony

There you go, now you can just push that button three times and cast all three DoTs.

"But what if it dies before I finish casting all three? I'm stuck at the end of the sequence again, and I don't wanna set no timer!"

That's ok, we can use the other options. If you set 'reset=target' then any time you change targets, it will reset the sequence back to the beginning. You can also set 'reset=combat', and the game will reset your sequence any time you leave combat. If you use the '/' operator (remember it, from earlier?) you can combine reset options!

/castsequence reset=combat/target Corruption, Immolate, Curse of Agony

There, now any time you change targets (like, if the old target is almost dead and you want to start on a new one), or any time you leave combat (perhaps the critter died before you finished casting all the dots), it resets your sequence for you, leaving you ready to start over.
Back to top Go down
View user profile


Posts : 26
Join date : 2007-07-31

Macro help Empty
PostSubject: Re: Macro help   Macro help Icon_minitimeThu Aug 02, 2007 10:06 pm

Kind of long but it helped me many many many times Very Happy

( P.S read the /castsequance part u can just simply press one button the whole fight >Smile )

Back to top Go down
View user profile

Posts : 30
Join date : 2007-07-27

Macro help Empty
PostSubject: Re: Macro help   Macro help Icon_minitimeThu Aug 02, 2007 10:57 pm

Nice post afro

Macro help Pbucket
Back to top Go down
View user profile http://karma.forumotion.com
Sponsored content

Macro help Empty
PostSubject: Re: Macro help   Macro help Icon_minitime

Back to top Go down
Macro help
Back to top 
Page 1 of 1
 Similar topics
» At the feet of a Macro Dorumon. (Anyone)
» How to setup record macro

Permissions in this forum:You cannot reply to topics in this forum
 :: Karma :: General chat-
Jump to: